.TITLE	DRDAR
	.IDENT	/04/
 
;
; Copyright (c) 1995-1999 by Mentec, Inc., U.S.A.
; All rights reserved
;
; THIS SOFTWARE IS FURNISHED UNDER A LICENSE AND MAY ONLY BE USED
; OR COPIED IN ACCORDANCE WITH THE TERMS OF SUCH LICENSE.
;
; VERSION 04
;
; D. N. CUTLER 30-AUG-73
;
; PREVIOUSLY MODIFIED BY:
;
;	T. J. MILLER
;
; MODIFIED BY:
;
;	T. J. MILLER 14-AUG-77
;
;		TM099 -- REMOVE UNEEDED CONDITIONALIZATION FOR RSX-11M+.
;
; DISABLE/ENABLE AST RECOGNITION DIRECTIVES
;
; MACRO LIBRARY CALLS
;

	.MCALL	TCBDF$
	TCBDF$			;DEFINE TASK CONTROL BLOCK OFFSETS

;+
; **-$DRDAR-DISABLE AST RECOGNITION
;
; THIS DIRECTIVE INSTRUCTS THE SYSTEM TO DISABLE RECOGNITION OF ASYNCHRONOUS
; SYSTEM TRAPS FOR THE ISSUING TASK. FURTHER AST'S ARE QUEUED AS THEY OCCUR
; AND WILL BE EFFECTED WHEN AST RECOGNITION IS ENABLED.
;
; DPB FORMAT:
;
;	WD. 00 -- DIC(99.),DPB SIZE(1.).
;
; INPUTS:
;
;	R2=ADDRESS OF THE TASK STATUS WORD OF THE CURRENT TASK.
;	R3=ADDRESS OF THE LAST WORD IN THE DPB+2.
;	R4=ADDRESS OF THE HEADER OF THE CURRENT TASK.
;	R5=ADDRESS OF THE TCB OF THE CURRENT TASK.
;
; OUTPUTS: (DIRECTIVE STATUS AND PS RETURNED TO TASK)
;
;	C=0 IF DIRECTIVE IS SUCCESSFULLY COMPLETED.
;		DIRECTIVE STATUS OF +1 IS RETURNED.
;	C=1 IF DIRECTIVE REJECTED.
;		DIRECTIVE STATUS OF 'D.RS8' IS RETURNED IF AST RECOG-
;			NITION IS ALREADY DISABLED.
;-
									
	.ENABL	LSB
$DRDAR::BIT	#T2.DST,(R2)	;AST RECOGNITION ALREADY DISABLED?
	BNE	10$		;IF NE YES
	BIS	#T2.DST,(R2)	;DISABLE AST RECOGNITION
	RETURN			;RETURN DIRECTIVE STATUS OF +1

;+
; **-$DREAR-ENABLE AST RECOGNITION
;
; THIS DIRECTIVE INSTRUCTS THE SYSTEM TO RECOGNIZE ASYNCHORONOUS SYSTEM
; TRAPS FOR THE ISSUING TASK. AST'S THAT HAVE BEEN QUEUED WHILE AST RECOG-
; NITION WAS DISABLED ARE EFFECTED IMMEDIATELY.
;
; DPB FORMAT:
;
;	WD. 00 -- DIC(101.),DPB SIZE(1.).
;
; INPUTS:
;
;	R2=ADDRESS OF THE TASK STATUS WORD OF THE CURRENT TASK.
;	R3=ADDRESS OF THE LAST WORD IN THE DPB+2.
;	R4=ADDRESS OF THE HEADER OF THE CURRENT TASK.
;	R5=ADDRESS OF THE TCB OF THE CURRENT TASK.
;
; OUTPUTS: (DIRECTIVE STATUS AND PS RETURNED TO TASK)
;
;	C=0 IF DIRECTIVE IS SUCCESSFULLY COMPLETED.
;		DIRECTIVE STATUS OF +1 IS RETURNED.
;	C=1 IF DIRECTIVE IS REJECTED.
;		DIRECTIVE STATUS OF 'D.RS8' IS RETURNED IF AST RECOG-
;			NITION IS NOT DISABLED.
;-

$DREAR::BIT	#T2.DST,(R2)	;AST RECOGNITION DISABLED?
	BEQ	10$		;IF EQ NO
	BIC	#T2.DST,(R2)	;ENABLE AST RECOGNITION
	CALLR	$SETRT		;FORCE A REDISPATCHING OF PROCESSOR
10$:	DRSTS	D.RS8		;SET DIRECTIVE STATUS
	.DSABL	LSB
									
	.END